Adobe Flash Player

From wiki.adammorgan.org
Jump to: navigation, search

General Info

Deployment

Flash 16.0.0.305 Deployment

mms.cfg

Many per-computer settings are controlled by mms.cfg, a custom version of which should be copied to:

  • 32-bit Windows - %WINDIR%\System32\Macromed\Flash
  • 64-bit Windows - %WINDIR%\SysWow64\Macromed\Flash

This file can include the following: Disable auto-update

AutoUpdateDisable=1
SilentAutoUpdateEnable=0

Disable video hardware acceleration (hardware acceleration is generally enabled by default, but can cause problems on thin clients)

DisableHardwareAcceleration=1

Use WAV audio player (by default Flash uses the Windows Core Audio APIs). If this option is set to 1, Flash Player will use WAV Audio for playback instead of the Windows Core Audio APIs. Use this option if you face audio playback problems in Flash Player on Windows 7 or higher.

UseWAVPlayer=1

Install Script

@ECHO OFF
::installs newest version of flash
::supports Win vista/7/8 x32/x64.
::NOTE: Win8 gets ActiveX (IE) Flashplayer updates through WSUS, so this script
::      only installs the Plugin (Firefox) version on Win8 machines.
 
CLS
:variables
SET _storeserver=MYFILESERVER
SET p_log=C:\MYORG\general.log
::set variable for x86/x64 reg
SET _configdir=%WINDIR%\SysWow64\Macromed\Flash
IF %PROCESSOR_ARCHITECTURE%==x86 SET _configdir=%WINDIR%\System32\Macromed\Flash
::set variables common to both activex and flash
SET _softwarever=16.0.0.305
SET verdir=Flash16_0_0_305
::set variable for last version, which is used to point to the uninstaller
REM SET lastverdir=Flash11_8_800_94
::initialize _os
SET _os=0
 
ECHO %date% %time% %~0 Started >> %p_log%
 
:install_activex
::Win8 gets IE flash updates through WSUS, so skip to plugin if os is win8
ver | find "6.2.9200" > nul
if %ERRORLEVEL%==0 set _os=win8
ver | find "6.2.9600" > nul
if %ERRORLEVEL%==0 set _os=win8
IF %_os%==win8 GOTO install_plugin
::install activex
SET _type=ActiveX
SET _installer=install_flash_player_16_active_x.msi
::set log path for msi installation
SET flashlog=C:\MYORG\logs\%verdir%_%_type%.log
::download install files and install
COPY /Y \\%_storeserver%\netinstalls\flashplayer\%verdir%\%_installer% %windir%\temp
COPY /Y \\%_storeserver%\netinstalls\flashplayer\%verdir%\%_type%.mst %windir%\temp
START /WAIT msiexec /i %windir%\temp\%_installer% /L* "%flashlog%" TRANSFORMS=%windir%\temp\%_type%.mst /passive
::delete install files
DEL %windir%\temp\%_installer%
DEL %windir%\temp\%_type%.mst
 
:install_plugin
SET _type=Plugin
SET _installer=install_flash_player_16_plugin.msi
::set log path for msi installation
SET flashlog=C:\MYORG\logs\%verdir%_%_type%.log
::download install files and install
COPY /Y \\%_storeserver%\netinstalls\flashplayer\%verdir%\%_installer% %windir%\temp
COPY /Y \\%_storeserver%\netinstalls\flashplayer\%verdir%\%_type%.mst %windir%\temp
START /WAIT msiexec /i %windir%\temp\%_installer% /L* "%flashlog%" TRANSFORMS=%windir%\temp\%_type%.mst /passive
::delete install files
DEL %windir%\temp\%_installer%
DEL %windir%\temp\%_type%.mst

::copy mms.cfg to the proper folder (disables autoupdate)
IF NOT EXIST %_configdir% MKDIR %_configdir%
copy /Y \\%_storeserver%\netinstalls\flashplayer\%verdir%\mms.cfg %_configdir%
::remove scheduled task for flash updater (if present)
schtasks /delete /tn "adobe flash player updater" /f >NUL
 
:flashinstall_eof
ECHO %date% %time% %~0 Finished >> %p_log%